Home Microsoft SQL Server DigiMailing iRN Contact
    Keyword



sys.sp_IHhelparticle

  No additional text.


Syntax


-- Name: sp_IHhelparticle

-- Description: Retrieve article properties. Invoked by sp_helparticle

-- Returns: 1 or 0

-- NOTE:
--		RMO flag tells helparticle to report extended
--		HREPL columns (which will be NULL for SQL publishers)


create procedure sys.sp_IHhelparticle
(
    @publication    sysname,
    @article        sysname,
    @returnfilter   bit,
    @publisher      sysname,
    @publisher_type sysname,
    @found          int OUTPUT,
    @rmo			bit = 0
)
AS
BEGIN
    DECLARE @retcode        int
    DECLARE @pubid          int
    DECLARE @article_name   sysname
    DECLARE @username       sysname

	CREATE TABLE #ORAtablespaceinfo
	(
		article_id int,
		tablespace sysname
	)

    SET NOCOUNT ON

    SELECT @username = suser_sname(), @found = 0

    IF @publisher IS NULL
    BEGIN
        RAISERROR (14043, 16, -1, '@publisher', 'sp_IHhelparticle')
        RETURN (1)
    END

    /*
    ** Parameter Check:  @publication.
    ** Check to make sure that there are some articles
    ** to display.
    */

    IF @publication IS NULL
    BEGIN
        RAISERROR (14043, 16, -1, '@publication', 'sp_IHhelparticle')
        RETURN (1)
    END

    EXECUTE @retcode = dbo.sp_validname @publication

    IF @retcode <> 0
    BEGIN
        RETURN (1)
    END

    /*
    ** Security Check. Restrict to 'sysadmin', PAL
    */
    exec @retcode = sys.sp_MSreplcheck_pull @publication    = @publication,
                                            @given_login    = @username,
                                            @publisher      = @publisher

    IF @retcode <> 0 OR @@error <> 0
    BEGIN
        RETURN (1)
    END

    /*
    ** Parameter Check:  @article.
    ** Check to make sure that the article exists, that it conforms
    ** to the rules for identifiers, and that it isn't NULL.
    */

    IF @article IS NULL
    BEGIN
        RAISERROR (14043, 16, -1, '@article', 'sp_IHhelparticle')
        RETURN (1)
    END

    -- Verify publication exists
	SELECT @pubid = sys.fn_MSrepl_getpubid(@publication, @publisher, @publisher_type)

    IF (@pubid IS NULL)
    BEGIN
        RAISERROR (20026, 11, -1, @publication)
        RETURN (1)
    END

    -- Verify article exists if specified
    IF @article <> '%'
    BEGIN
        IF NOT EXISTS
        (
            SELECT  *
            FROM    IHarticles
            WHERE   name = @article
              AND   publication_id = @pubid
        )
        BEGIN
            RAISERROR (20027, 11, -1, @article)
            RETURN (1)
        END
    END

	IF (@publisher_type LIKE N'ORACLE%')
	BEGIN
		EXEC sp_ORAhelparticle	@pubid        = @pubid,
								@article      = @article,
								@returnfilter = @returnfilter,
								@publisher    = @publisher,
								@found        = @found OUTPUT,
								@rmo		  = @rmo
	END
	ELSE
	BEGIN
		RAISERROR (21643, 16, -1, '@publisher_type')
		RETURN (1)
	END

    RETURN (0)
END

 
Last revision 2008RTM
See also

  sp_helparticle (Procedure)
sp_MSdrop_repltran (Procedure)
sp_MSrepl_helparticlermo (Procedure)
       



News

  Query a named instance
Sybase+ASE+silent+install
SQL 2008 R2
Deprecated procedures in SQL2008
Reporting Services item-level role definitions
Create all your missing indexes
Converting datetime field
Start MSSQL Server Profiler at time
Replicating MSSQL Server views
Exploring Microsoft Sharepoint
The OLE DB provider "SQLNCLI10" for linked server indicates.
Mobile solar charger
Oracle to SQL Server replication
Cannot insert the value NULL into column
Undocumented Microsoft SQL Server 2008
VMware
Zoekmachine optimalisatie
SQL Servers hidden objects
FckEditor
Flash in Ajax
De hype die AJAX heet
Barcode scannen
MySQL; Gratis, makkelijk en snel!
PHP
sIFR; de combinatie tussen HTML en Flash