create procedure sys.sp_help_log_shipping_secondary_primary
(
    @primary_server sysname -- cannot be NULL
    ,@primary_database sysname -- cannot be NULL
)
as
begin
    set nocount on
    declare @retcode int

    
    -- security check
    
    exec @retcode = sys.sp_MSlogshippingsysadmincheck
    if (@retcode != 0 or @@error != 0)
        return 1
    
    -- must be invoked from master db
    
    if (db_name() != N'master')
    begin
        raiserror(5001, 16,-1)
        return 1
    end
    
    -- select the result from log_shipping_secondary
    
    select
        secondary_id
        ,primary_server
        ,primary_database
        ,backup_source_directory
        ,backup_destination_directory
        ,file_retention_period
        ,copy_job_id
        ,restore_job_id
        ,'monitor_server' = case when (user_specified_monitor = 1) then monitor_server else cast(NULL as sysname) end
        ,'monitor_server_security_mode' = case when (user_specified_monitor = 1) then monitor_server_security_mode else cast(NULL as bit) end
    from msdb.dbo.log_shipping_secondary
    where primary_server = upper(@primary_server)
        and primary_database = @primary_database
    
    -- all done
    
    return 0
end